Geospatial data visualizations

Geospatial data can be visualized as part of your query using the render operator as points, pies, or bubbles on a map.

Examples

The following example finds storm events and visualizes 100 on a map.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

The following example visualizes multiple series of points, where the [Longitude, Latitude] pair defines each point, and a third column defines the series. In this example, the series is EventType.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

The following example visualizes a series of points on a map. If you have multiple columns in the result, you must specify the columns to be used for xcolumn (Longitude), ycolumn (Latitude), and series.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

The following example visualizes points on the map using GeoJSON dynamic values to define the points.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

The following example shows storm events aggregated by S2 cells. The chart aggregates events in bubbles by location in one color.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map)

The following example shows storm events aggregated by S2 cells. The chart aggregates events by event type in pie charts by location.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map)

Related content

• Render operator
• Data analytics for automotive test fleets (geospatial clustering use case)
• Learn about Azure architecture for geospatial data processing and analytics