bag_pack()

Creates a dynamic property bag object from a list of keys and values.

Syntax

bag_pack(key1, value1, key2, value2,... )

Parameters

Returns

Returns a dynamic property bag object from the listed key and value inputs.

Examples

Example 1

The following example creates and returns a property bag from an alternating list of keys and values.

print bag_pack("Level", "Information", "ProcessID", 1234, "Data", bag_pack("url", "www.bing.com"))

Results

Example 2

The following example creates a property bag and extract value from property bag using ‘.’ operator.

datatable (
    Source: int,
    Destination: int,
    Message: string
) [
    1234, 100, "Hi", 
    4567, 200, "Hello",
    1212, 300, "Hey" 
]
| extend MyBag=bag_pack("Dest", Destination, "Text", Message)
| project-away Source, Destination, Message
| extend MyBag_Dest=MyBag.Dest, MyBag_Text=MyBag.Text

Results

Example 3

The following example uses two tables, SmsMessages and MmsMessages, and returns their common columns and a property bag from the other columns. The tables are created ad-hoc as part of the query.

SmsMessages

MmsMessages

let SmsMessages = datatable (
    SourceNumber: string,
    TargetNumber: string,
    CharsCount: string
) [
    "555-555-1234", "555-555-1212", "46", 
    "555-555-1234", "555-555-1213", "50",
    "555-555-1212", "555-555-1234", "32" 
];
let MmsMessages = datatable (
    SourceNumber: string,
    TargetNumber: string,
    FileSize: string,
    FileName: string
) [
    "555-555-1212", "555-555-1213", "200", "Pic1",
    "555-555-1234", "555-555-1212", "250", "Pic2",
    "555-555-1234", "555-555-1213", "300", "Pic3"
];
SmsMessages 
| join kind=inner MmsMessages on SourceNumber
| extend Packed=bag_pack("CharsCount", CharsCount, "FileSize", FileSize, "FileName", FileName) 
| where SourceNumber == "555-555-1234"
| project SourceNumber, TargetNumber, Packed

Results

Related content

• pack-all function
• bag-unpack plugin