extract()

Learn how to use the extract() function to get a match for a regular expression from a source string.

Get a match for a regular expression from a source string.

Optionally, convert the extracted substring to the indicated type.

Syntax

extract(regex, captureGroup, source [, typeLiteral])

Parameters

NameTypeRequiredDescription
regexstring✔️A regular expression.
captureGroupint✔️The capture group to extract. 0 stands for the entire match, 1 for the value matched by the first ‘(‘parenthesis’)’ in the regular expression, and 2 or more for subsequent parentheses.
sourcestring✔️The string to search.
typeLiteralstringIf provided, the extracted substring is converted to this type. For example, typeof(long).

Returns

If regex finds a match in source: the substring matched against the indicated capture group captureGroup, optionally converted to typeLiteral.

If there’s no match, or the type conversion fails: null.

Examples

Extract month from datetime string

The following query extracts the month from the string Dates and returns a table with the date string and the month.

let Dates = datatable(DateString: string)
[
    "15-12-2024",
    "21-07-2023",
    "10-03-2022"
];
Dates
| extend Month = extract(@"-(\d{2})-", 1, DateString, typeof(int))
| project DateString, Month

Output

DateStringMonth
15-12-202412
21-07-20237
10-03-20223

Extract username from a string

The following example returns the username from the string. The regular expression ([^,]+) matches the text following “User: " up to the next comma, effectively extracting the username.

let Text = "User: JohnDoe, Email: johndoe@example.com, Age: 29";
print UserName = extract("User: ([^,]+)", 1, Text)

Output

UserName
JohnDoe

Related content