ipv6_is_match()
Learn how to use the ipv6_is_match() function to match two IPv6 or IPv4 network address strings.
Matches two IPv6 or IPv4 network address strings. The two IPv6/IPv4 strings are parsed and compared while accounting for the combined IP-prefix mask calculated from argument prefixes, and the optional prefix argument.
Syntax
ipv6_is_match(ip1,ip2[ ,prefix])
Parameters
| Name | Type | Required | Description |
|---|---|---|---|
| ip1, ip2 | string | ✔️ | An expression representing an IPv6 or IPv4 address. IPv6 and IPv4 strings can be masked using IP-prefix notation. |
| prefix | int | An integer from 0 to 128 representing the number of most-significant bits that are taken into account. |
Returns
true: If the long representation of the first IPv6/IPv4 string argument is equal to the second IPv6/IPv4 string argument.false: Otherwise.null: If conversion for one of the two IPv6/IPv4 strings wasn’t successful.
Examples
IPv6/IPv4 comparison equality case - IP-prefix notation specified inside the IPv6/IPv4 strings
datatable(ip1_string:string, ip2_string:string)
[
// IPv4 are compared as IPv6 addresses
'192.168.1.1', '192.168.1.1', // Equal IPs
'192.168.1.1/24', '192.168.1.255', // 24 bit IP4-prefix is used for comparison
'192.168.1.1', '192.168.1.255/24', // 24 bit IP4-prefix is used for comparison
'192.168.1.1/30', '192.168.1.255/24', // 24 bit IP4-prefix is used for comparison
// IPv6 cases
'fe80::85d:e82c:9446:7994', 'fe80::85d:e82c:9446:7994', // Equal IPs
'fe80::85d:e82c:9446:7994/120', 'fe80::85d:e82c:9446:7998', // 120 bit IP6-prefix is used for comparison
'fe80::85d:e82c:9446:7994', 'fe80::85d:e82c:9446:7998/120', // 120 bit IP6-prefix is used for comparison
'fe80::85d:e82c:9446:7994/120', 'fe80::85d:e82c:9446:7998/120', // 120 bit IP6-prefix is used for comparison
// Mixed case of IPv4 and IPv6
'192.168.1.1', '::ffff:c0a8:0101', // Equal IPs
'192.168.1.1/24', '::ffff:c0a8:01ff', // 24 bit IP-prefix is used for comparison
'::ffff:c0a8:0101', '192.168.1.255/24', // 24 bit IP-prefix is used for comparison
'::192.168.1.1/30', '192.168.1.255/24', // 24 bit IP-prefix is used for comparison
]
| extend result = ipv6_is_match(ip1_string, ip2_string)
Output
| ip1_string | ip2_string | result |
|---|---|---|
| 192.168.1.1 | 192.168.1.1 | 1 |
| 192.168.1.1/24 | 192.168.1.255 | 1 |
| 192.168.1.1 | 192.168.1.255/24 | 1 |
| 192.168.1.1/30 | 192.168.1.255/24 | 1 |
| fe80::85d:e82c:9446:7994 | fe80::85d:e82c:9446:7994 | 1 |
| fe80::85d:e82c:9446:7994/120 | fe80::85d:e82c:9446:7998 | 1 |
| fe80::85d:e82c:9446:7994 | fe80::85d:e82c:9446:7998/120 | 1 |
| fe80::85d:e82c:9446:7994/120 | fe80::85d:e82c:9446:7998/120 | 1 |
| 192.168.1.1 | ::ffff:c0a8:0101 | 1 |
| 192.168.1.1/24 | ::ffff:c0a8:01ff | 1 |
| ::ffff:c0a8:0101 | 192.168.1.255/24 | 1 |
| ::192.168.1.1/30 | 192.168.1.255/24 | 1 |
IPv6/IPv4 comparison equality case- IP-prefix notation specified inside the IPv6/IPv4 strings and as additional argument of the ipv6_is_match() function
datatable(ip1_string:string, ip2_string:string, prefix:long)
[
// IPv4 are compared as IPv6 addresses
'192.168.1.1', '192.168.1.0', 31, // 31 bit IP4-prefix is used for comparison
'192.168.1.1/24', '192.168.1.255', 31, // 24 bit IP4-prefix is used for comparison
'192.168.1.1', '192.168.1.255', 24, // 24 bit IP4-prefix is used for comparison
// IPv6 cases
'fe80::85d:e82c:9446:7994', 'fe80::85d:e82c:9446:7995', 127, // 127 bit IP6-prefix is used for comparison
'fe80::85d:e82c:9446:7994/127', 'fe80::85d:e82c:9446:7998', 120, // 120 bit IP6-prefix is used for comparison
'fe80::85d:e82c:9446:7994/120', 'fe80::85d:e82c:9446:7998', 127, // 120 bit IP6-prefix is used for comparison
// Mixed case of IPv4 and IPv6
'192.168.1.1/24', '::ffff:c0a8:01ff', 127, // 127 bit IP6-prefix is used for comparison
'::ffff:c0a8:0101', '192.168.1.255', 120, // 120 bit IP6-prefix is used for comparison
'::192.168.1.1/30', '192.168.1.255/24', 127, // 120 bit IP6-prefix is used for comparison
]
| extend result = ipv6_is_match(ip1_string, ip2_string, prefix)
Output
| ip1_string | ip2_string | prefix | result |
|---|---|---|---|
| 192.168.1.1 | 192.168.1.0 | 31 | 1 |
| 192.168.1.1/24 | 192.168.1.255 | 31 | 1 |
| 192.168.1.1 | 192.168.1.255 | 24 | 1 |
| fe80::85d:e82c:9446:7994 | fe80::85d:e82c:9446:7995 | 127 | 1 |
| fe80::85d:e82c:9446:7994/127 | fe80::85d:e82c:9446:7998 | 120 | 1 |
| fe80::85d:e82c:9446:7994/120 | fe80::85d:e82c:9446:7998 | 127 | 1 |
| 192.168.1.1/24 | ::ffff:c0a8:01ff | 127 | 1 |
| ::ffff:c0a8:0101 | 192.168.1.255 | 120 | 1 |
| ::192.168.1.1/30 | 192.168.1.255/24 | 127 | 1 |
Related content
- Overview of IPv4/IPv6 functions
Feedback
Was this page helpful?
Glad to hear it! Please tell us how we can improve.
Sorry to hear that. Please tell us how we can improve.